Hey guys,
as I got tired of shuffling around files whenever I want to play either Xtv4 or v1.4 I created a little batch script-based launcher. It is similar to a launcher by Jugatsu I have seen except that this one is purely written as a (very lightweight) batch script. It has a menu which lets you choose the game version you want to play. I don't know if it would work with Vista so please let me know about this.
Instructions:
1. Create a txt file and copy the following code into it:
:: FarCry XTv4 Launcher with Menu v1.0
:: created by [CrY] FoX, fox(at)cryclan.co.uk
@echo off
::Set the Path to the FarCry directory here!
set fcdir="C:\Program Files\Ubisoft\Crytek\Far Cry\"
::Set any FarCry parameters here!
set fcparam=""
if not exist %fcdir%.\bin32\crygame.dll goto wrongdir
:STARTMENU
cls
echo. Start FarCry XTv4...............1
echo. Start FarCry v1.4...............2
echo. Quit the XT Launcher............3
echo.
choice /n /c:123 /t:1,10 " Please choose "
if errorlevel 3 goto cleanup
if errorlevel 2 goto FC
goto XT
:XT
echo.
xcopy /y %fcdir%.\eXcaliTrone_Home\bin32\crygame.dll %fcdir%.\bin32\
if not exist %fcdir%.\fcdata\xt_v4.pak copy /y %fcdir%.\eXcaliTrone_Home\FCDATA\xt_v4.pak %fcdir%.\fcdata\
%fcdir%.\Bin32\FarCry.exe %fcparam%
goto cleanup
:FC
echo.
xcopy /y %fcdir%.\original_crygame.dll_1.4\crygame.dll %fcdir%.\bin32\
if exist %fcdir%.\fcdata\xt_v4.pak del /q %fcdir%.\fcdata\xt_v4.pak
%fcdir%.\Bin32\FarCry.exe %fcparam%
goto cleanup
:WRONGDIR
echo.
echo.*** The correct path to FarCry was not specified. ***
echo.*** Please update the path in the XTLauncher.CMD! ***
echo.
pause.
:CLEANUP used variables
for %%v in (fcdir fcparam) do set %%v=
:EOF
In line 6 you can edit the path to your FarCry directory. It is currently set to the English language default directory. In line 8 you can edit any parameters like your UBI login or keybinds. By default this setting is empty. Afterwards save the file.
2. Rename the file to "XTLauncher.cmd" and place it in any directory. (As it works with absolute paths it can be anywhere.) It might be wise not to place it in the FC directory so that XTv4 doesn't prompt you to clean up any unnecessary files.
3. In order for the menu to work you need a little file called "choice.com" which used to be included in older versions of Windows.
You can download it here:
ftp.microsoft.com/Services/TechNet/Windows/msdos/RESKIT/SUPPDISK/CHOICE.COM.
4. Place choice.com either into the same directory as xtlauncher.cmd or into a directory which is specified in the path variable of your Windows, e.g c:\windows\system32. If you do the latter you can use choice easily in other batch scripts as well without multiple copies.
5. Now you can start either game simply by executing (doubleclicking) xtlauncher.cmd. You can also point your FC link (e.g. on your dektop) to the xtlauncher.cmd for added convenience.
That's it. Enjoy! Feedback would be very welcome.
I might add that the script could easily be adapted to serve as a launcher for additional game versions like XTv3 etc. It also might be an option to use 2 scripts - one for each game version - instead of one with a menu. This would also make the use of choice.com unnecessary. If somebody would be interested in that just let me know.
Cheers,
[CrY] FoX